Description

It's a box! But it's no ordinary box - it's a drum box.

It's collaborative, like a drum circle, portable, and customizable (i.e. you can upload any beat that you want to map to a drum pad and change it around at will).

Components

A large purple tub (not quite a box - but box sounded better than tub), 4 red leds, 4 fsrs, 4 cardboard circles, bubble wrap, breadboard, resistors, and a lot of wire

Arduino Code

Processing Code

// Analysis
// by Krister Olsson <http://www.tree-axis.com>
// extended a tad bit by n8agrin

// Plays an MP3 while displaying an oscilloscope
// and performing real-time spectrum analysis.
// Click to start/stop
// Created 1 May 2005
// Updated 18 May 2006
// Updated for TUI lab, Nov 8th, 2007

import krister.Ess.*;
import processing.serial.*;

// Setup a port
Serial port;
String portname = "/dev/tty.usbserial-A4001nvG";

// Establish output channels and buffers
AudioChannel[] channels = new AudioChannel[4];
int[] bufferSizes = new int[4];
int[] bufferDurations = new int[4];
FFT[] FFTs = new FFT[4];

// bground for the visualization
int bg = 1;

void setup() {
  // Create the serial connection
  port = new Serial(this, portname, 9600);
 
  // Size of the vis window
  size(1024,200);

  // start up Ess
  Ess.start(this);
 
  // Setup the drum hits
  channels[0] = new AudioChannel("drum1.wav");
  channels[1] = new AudioChannel("drum2.wav");
  channels[2] = new AudioChannel("drum3.wav");
  channels[3] = new AudioChannel("drum4.wav");
 
  for (int i=0; i<channels.length; i++){
   bufferSizes[i] = channels[i].buffer.length;
   bufferDurations[i] = channels[i].ms(bufferSizes[i]);
   FFTs[i] = new FFT(512);
  }
 
  // set the frame rate for the vis
  frameRate(30);
  noSmooth(); // no harsh, either, but hey what the heck
}

void draw() {
  if (bg < 254) {
    bg++;
  }
  else {
    bg = 1;
  }
  background(bg,110,255);
  drawSpectrum();
  drawSamples();
}

void drawSpectrum() {
  noStroke();
  for (int i=0; i < channels.length; i++) {
    FFTs[i].getSpectrum(channels[i]);
  }
}

void drawSamples() {
  stroke(255);
 
  for (int j=0; j < channels.length; j++) {
  // interpolate between 0 and writeSamplesSize over writeUpdateTime
  int interp=(int)max(0,(((millis()-channels[j].bufferStartTime)/(float)bufferDurations[j])*bufferSizes[j]));

  for (int i=0;i<1024;i++) {
    float left=100;
    float right=100;

    if (i+interp+1<channels[j].buffer2.length) {
      left-=channels[j].buffer2[i+interp]*75.0;
      right-=channels[j].buffer2[i+1+interp]*75.0;
    }

    line(i,left,i+1,right);
  }
  }
}

void serialEvent(Serial p) {
   playSample((char) p.read());
}

void keyPressed() {
  playSample(key);
}

void playSample(char letter) {
  switch(letter) {
    case 'a':
      channels[0].play();
      break;
    case 'b':
      channels[1].play();
      break;
    case 'c':
      channels[2].play();
      break;
    case 'd':
      channels[3].play();
      break;
    default:
      for(int i=0; i<channels.length; i++) {
        if (channels[i].state == Ess.PLAYING) {
          channels[i].stop();
        }
      }
      break;
  }
}

// clean up Ess before exiting
public void stop() {
  Ess.stop();
  super.stop();
}

Pictures